Tugas 5
Analisa Transistor Bipolar Dengan Program PISCES
Pertama kali kita masukkan doping profile yang kita miliki ke dalam file bipolar.gr0. Dalam file ini nilai-nilai parameternya didapatkan dari tahap desain sebelumnya.
Title File : bipolar.gr0
$ Tugas EL-312 (Devais Mikroelektronika)
$ Grid of the structure and doping distribution
mesh rect nx=31 ny=31 smooth=1 diag.flip outf=doping.bip
x.m n=1 l=0.0 r=1.0
x.m n=31 l=300.0 r=1.0
y.m n=1 l=0.0 r=1.0
y.m n=31 l=90.0 r=1.0
$ Electrodes #1 Emitter; #2 Base; #3 Collector
region num=1 iy.l=1 iy.h=31 ix.l=1 ix.h=31 silicon
elec num=1 ix.l=1 ix.h=8 iy.l=1 iy.h=1
elec num=2 ix.l=28 ix.h=31 iy.l=1 iy.h=1
elec num=3 ix.l=1 ix.h=31 iy.l=31 iy.h=31
$ Impurity Profile
doping uniform conc=1.0e15 n.type
doping gauss conc=5.0e18 p.type junc=25.0
doping gauss conc=5.0e19 n.type junc=10.0 x.r=85.0 ratio=0.75
$ Plotting
plot.1d dop x.s=0.0 x.e=300.0 y.s=0.0 y.e=0.0 abs log points pa
plot.1d dop x.s=0.00 x.e=0.0 y.s=0.0 y.e=90.0 abs log points pa
plot.2d grid boundary l.elect=1 l.bound=3 l.junct=6 pa
plot.2d junction boundary l.elect=1 l.bound=3 l.junct=6 no.fill pa
end
Kita dapatkan output plot :
Title File : bipolar.gr1
$ Tugas EL-312 (Devais Mikroelektronika)
$ Solution with 18.0 V applied to collector
mesh inf=doping.bip
mater region=1 taup0=3.5e-7 taun0=1.1e-6
models srh auger conmob fldmob
$ Solve initial condition with zero carriers
symb gummel carr=0
method iccg damped
solve init
solve v3=18 local
$ Then redo with 2 carriers
symb newton carr=2
method xnorm autonr
solve v3=18 outf=bip1
end
Title File : bipolar.gr2
$ Tugas EL-312 (Devais Mikroelektronika)
$ Forward characteristic simulation
mesh inf=doping.bip
mater region=1 taup0=3.5e-7 taun0=1.1e-6
models srh auger conmob fldmob
load inf=bip1
log outf=bip2
symb newton carr=2
method xnorm autonr
solve v3=18 v2=0.1
solve previous v2=0.2 vstep=0.1 nstep=5 electr=2
solve previous v2=0.8 outf=bipsolv1
solve previous v2=0.9 outf=bipsolv2
solve previous v2=1.0 outf=bipsolv3
end
Title File : bipolar.gr3
$ Tugas EL-312 (Devais Mikroelektronika)
$ Frequency analysis
mesh inf=doping.bip
mater region=1 taup0=3.5e-7 taun0=1.1e-6
models srh auger conmob fldmob
load inf=bipsolv1
symb newton carr=2
method xnorm autonr
log acfile=ac.bip
solve ac freq=1 fstep=3 mult.f nfstep=10 vss=0.01
+ max.inner=250 s.omega=0.30 terminal=2
end
Title File : bipolar.if1
$ Tugas EL-312 (Devais Mikroelektronika)
$ Plot Ib vs Frequency
mesh inf=doping.bip
plot.1d inf=ac.bip x.ax=freq x.log x.min=0.0 y.label=Ib y.ax=i2 abs
+ title="Ib thd Frekuensi" pa
end
Output plot :
Title File : bipolar.if2
$ Tugas 5 EL-312 (Devais Mikroelektronika)
$ Plot Ic vs Frequency
mesh inf=doping.bip
plot.1d inf=ac.bip x.ax=freq x.log x.min=0.0 y.label=Ic y.ax=i3 abs
+ title="Ic thd Frekuensi" pa
end
O utput plot :
Title File : bipolar.iv1
$ Tugas EL-312 (Devais Mikroelektronika)
$ plotting forward characteristic
mesh inf=doping.bip
plot.1d inf=bip2 x.ax=v2 y.ax=i3 x.label=Vbe y.label="Ib & Ic"
+ y.log min.value=-11 x.min=0.4 points
+ title="Ib & Ic thd Vbe"
plot.1d inf=bip2 x.ax=v2 y.ax=i2
+ y.log min.value=-11 x.min=0.4 points unch pa
end
|